☰

Windows コマンドプロンプトのエイリアス 質問する

tag-icon • tag-icon windows notepad++ alias command-prompt
Windows コマンドプロンプトのエイリアス 質問する

notepad++.exe環境変数にパスを追加しました。

今、コマンドプロンプトで、notepad++.exe filename.txtを開きます。しかし、私はファイルを開くことfilename.txtだけをしたいのです。np filename.txt

を使用しようとしましたDOSKEY np=notepad++。しかし、ファイルを開かずに、すでに開いている Notepad++ を最前面に表示するだけです。ファイルを開くにはどうすればよいですか?

ベストアンサー1

ジョシュの回答に付け加えると、

以下の手順でエイリアスを永続化することができます。

  1. コマンドを含む .bat または .cmd ファイルを作成しますDOSKEY。

  2. regeditを実行してHKEY_CURRENT_USER\Software\Microsoft\Command Processor

  3. .bat/.cmd ファイルの名前AutoRunと完全パスを含む文字列値エントリを追加します。

    たとえば%USERPROFILE%\alias.cmd、パスの最初のセグメントを に置き換えると、%USERPROFILE%複数のマシン間で同期する場合に便利です。

この方法では、cmd が実行されるたびにエイリアスがロードされます。

Windows 10 または Windows 11 の場合は、代わりにエントリを追加しますHKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Command Processor。

(Windows 11 の場合、デフォルトでは「ターミナル アプリ」が PowerShell を指していることにも注意してください。コマンド プロンプトの場合は「cmd」を検索してください。)

完全を期すために、役に立つと思われるエイリアスの種類を示すテンプレートを次に示します。

@echo off

:: Temporary system path at cmd startup

set PATH=%PATH%;"C:\Program Files\Sublime Text 2\"

:: Add to path by command

DOSKEY add_python26=set PATH=%PATH%;"C:\Python26\"
DOSKEY add_python33=set PATH=%PATH%;"C:\Python33\"

:: Commands

DOSKEY ls=dir /B $*
DOSKEY sublime=sublime_text $*  
    ::sublime_text.exe is name of the executable. By adding a temporary entry to system path, we don't have to write the whole directory anymore.
DOSKEY gsp="C:\Program Files (x86)\Sketchpad5\GSP505en.exe"
DOSKEY alias=notepad %USERPROFILE%\Dropbox\alias.cmd

:: Common directories

DOSKEY dropbox=cd "%USERPROFILE%\Dropbox\$*"
DOSKEY research=cd %USERPROFILE%\Dropbox\Research\
  • 構文は、引数を取る実行可能ファイルだけでなく、ディレクトリ文字列の後でも機能することに注意してください$*。したがって、上記の例では、ユーザー定義のコマンドはdropbox researchと同じディレクトリを指しますresearch。
  • Rivenfall が指摘したように、ファイルを簡単に編集できるコマンドを含めることをお勧めしますalias.cmd。alias上記を参照してください。cmd セッションの場合は、Enter キーを押してcmdcmd を再起動し、ファイルを再読み込みしますalias.cmd。

この質問の答えをインターネットで検索したところ、どういうわけか、議論は永続性のみ、または DOSKEY の使用のみに焦点を当てていました。ここでこれら 2 つの側面が一緒になって、誰かが恩恵を受けられることを願っています。

.regのインストールに役立つファイルがありますalias.cmd。これは、上記のように、例として Dropbox フォルダに設定されています。

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"AutoRun"="%USERPROFILE%\\alias.cmd"

alias.cmdシングルユーザー アプリケーションの場合は、上記の方法で十分です。ただし、レジストリ キーに最初に存在するかどうかを確認する必要がある場合もあります。以下の例を参照してください。

C:\Users\Public\init.cmd潜在的にクロスユーザー構成をホストするファイルの場合:

@ECHO OFF
REM Add other configurations as needed
IF EXIST "%USERPROFILE%\alias.cmd" ( CALL "%USERPROFILE%\alias.cmd" )

レジストリ キーは、次のように更新するC:\Users\Public\init.cmdか、次の.regファイルを使用して更新する必要があります。

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"AutoRun"="C:\\Users\\Public\\init.cmd"

おすすめ記事