値の1つをスキップしながら変数を繰り返すには？

Question

出力ラインの順序を気にせずにPOSIX Awkを使用してください。

echo | awk -v 'netids=10 20 30' -v 'names=eth1 eth2 eth3' '
  BEGIN {
    netidcount = split(netids, netid)
    namecount = split(names, name)
    if (netidcount != namecount) {
      print "Error: You must pass the same number of names and netids."
      exit 1
    }
    for (i in name) {
      for (j in name) {
        if (i == j) {
          continue
        }
        printf "iptables -I FORWARD -i %s -src 192.168.%s.0/24 -dst 192.168.%s.0/24 -j DROP\n", name[i], netid[i], netid[j]
      }
    }
  }'

もちろんこれを変更できます。たとえば、上記のawkスクリプトをファイルに入れて、次のように呼び出すことができます。

echo | awk -v ... -v ... -f script.awk

data.txtまたは、ネットワークIDと名前を次の形式で入力できます。

eth1 10
eth2 20
eth3 30

script.awkそして、Awkスクリプトファイルを次のように作成します。

#!/bin/awk
NF != 2 {
  error = 1
  print "Error: Each line of input must contain one interface name and one number."
  exit
}
(($1 in nameseen) || ($2 in netidseen)) {
  error = 1
  print "Error: Each interface name and network id in input must be unique."
  exit
}
{
  name[NR] = $1
  netid[NR] = $2
  nameseen[$1]
  netidseen[$2]
}
END {
  if (error) {
    exit error
  }
  for (i in name) {
    for (j in name) {
      if (i == j) {
        continue
      }
      printf "iptables -I FORWARD -i %s -src 192.168.%s.0/24 -dst 192.168.%s.0/24 -j DROP\n", name[i], netid[i], netid[j]
    }
  }
}

次に、次のように呼び出します。

awk -f script.awk data.txt

多くのオプションがあります。

私はdata.txt次のように見えます：

eth1 192.168.10.0/24
eth2 192.168.20.0/24
eth3 192.168.30.0/24

このデータ型を使用するようにスクリプトを変更することは、読者の練習課題として残されます。 ;)

_{（注：このコードを使用している場合は、この回答へのリンクを帰属として含めることを忘れないでください。）}

Answer 1