たとえば、文字列があります。
1234567890
この文字列のランダムな位置を、他の文字列セットのランダムな順序でその位置に置き換えたいと思います。
ABCDEFGHIJ
KLMNOPQRST
UVWXYZABCD
...
3回の置換を選択した場合、スクリプトは3、7、8などの3つのランダム数と1、1、3などの3つのランダムシーケンスを選択して予想される出力を生成する必要があります。
12C456GB90
明らかなループなしでこれを行う方法はありますか?私はランダムな位置とランダムな行シーケンスを生成し、1回の置換を実行し、出力でプロセスを繰り返し、繰り返し、そして繰り返す単純なbashスクリプトを書いた。これはうまく機能しますが、実際のファイル(例よりはるかに大きい)では10,000を超える代替アイテムを作成しようとしています。ああ、そして複数の「突然変異」修飾配列を生成するには、これを何度も実行する必要があります。
編集:現在、次のようなものを使用しています。
#chose random number between 1 and the number of characters in the string
randomposition=$(jot -r 1 1 $seqpositions)
#chose a random number between 1 and the number of lines in the set of potential replacement strings
randomline=$(jot -r 1 1 $alignlines)
#find the character at randomline:randomposition
newAA=$(sed -n "$randomline,$randomline p" $alignmentfile | cut -c$randomposition)
#replace the character at 'string:randomposition' with the character at 'randomline:randomposition'
sed "s/./$newAA/$randomposition" $sequencefile
(明らかに少し余分なビットがあります)何千回も繰り返します。
ベストアンサー1
メモ:
これはそんなに楽しみのためのものです。の同等のプログラムはC
はるかに簡単で、はるかに高速です。bash
私たちはそれについて話すことはありません。
次のperl
スクリプトは、私のラップトップで約10秒以内に約1Mのシーケンスリストと約10,000のソートリストを変更します。
#! /usr/bin/perl
# usage mutagen number_of_replacements alignment_file [ sequence_file ..]
use strict;
my $max = shift() - 1;
my $algf = shift;
open my $alg, $algf or die "open $algf: $!";
my @alg = <$alg>;
sub prand { map int(rand() * $_[0]), 0..$max }
while(<>){
my @ip = prand length() - 1;
my @op = prand scalar @alg;
for my $i (0..$max){
my $p = $ip[$i];
substr $_, $p, 1, substr $alg[$op[$i]], $p, 1;
}
print;
}
使用例:
$ cat seq
1634870295
5684937021
2049163587
6598471230
$ cat alg
DPMBHZJEIO
INTMJZOYKQ
KNTXGLCJSR
GLJZRFVSEX
SYJVHEPNAZ
$ perl mutagen 3 alg seq
1L3V8702I5
5684HE7Y21
2049JZC587
6598H7C2E0
生成されたn
乱数が異なる必要がある場合は、prand
次のように変更する必要があります。
sub prand {
my (@r, $m, %h);
die "more replacements than positions/alignments" if $max >= $_[0];
for(0..$max){
my $r = int(rand() * $_[0]);
$r = ($r + 1) % $_[0] while $h{$r};
$h{$r} = 1;
push @r, $r;
}
@r;
}
スイッチが与えられたときに色の変化をきれいに印刷するデバッグサポートバージョン-d
:
#! /usr/bin/perl
# usage mutagen [-d] number_of_replacements alignment_file [ sequence_file ..]
use strict;
my $debug = $ARGV[0] eq '-d' ? shift : 0;
my $max = shift() - 1;
my $algf = shift;
open my $alg, $algf or die "open $algf: $!";
my @alg = <$alg>;
sub prand { map int(rand() * $_[0]), 0..$max }
while(<>){
my @ip = prand length() - 1;
my @op = prand scalar @alg;
if($debug){
my $t = ' ' x (length() - 1);
substr $t, $ip[$_], 1, $ip[$_] for 0..$max;
warn "@ip | @op\n $_ $t\n";
for my $i (0..$max){
my $t = $alg[$op[$i]];
$t =~ s/(.{$ip[$i]})(.)/$1\e[1;31m$2\e[m/;
printf STDERR " %2d %s", $op[$i], $t;
}
}
for my $i (0..$max){
my $p = $ip[$i];
substr $_, $p, 1, substr $alg[$op[$i]], $p, 1;
}
print;
if($debug){
my @t = split "", $_;
for my $i (0..$max){
$_ = "\e[1;31m$_\e[m" for $t[$ip[$i]];
}
warn " = ", @t, "\n";
}
}