私のCSVファイルは次のとおりです
8 id1 xyz
1 id1 abcdef
2 id1 mv
1 id1 tzfl
6 id2 xyz
1 id2 abcdef
1 id2 mv
5 id3 xyz
2 id3 abcdef
...
8 id100 xyz
1 id100 abcdef
2 id100 mv
1 id100 tzfl
4 id100 glkgb
このファイルを同じIDでソートした後、次の形式で列3と列1を印刷したいと思います。
xyz abcdef mv tzfl glkgb
id1 8 1 2 1
id2 6 1 1
id3 5 2
...
id100 8 1 2 1 4
どんな提案にも感謝します！
ベストアンサー1
awk素晴らしいツールです。素晴らしいチュートリアルがありますawk。Awk - チュートリアルと紹介 - Bruce Barnett - Grymoire
この試み：
awk '
{
columns[$3]=1 ; ids[$2]=1 ; col1[$2 ":::" $3]=$1
if (maxcollen< length($1)) maxcollen=length($1)
if (maxcollen< length($2)) maxcollen=length($2)
if (maxcollen< length($3)) maxcollen=length($3)
}
END {
printf("%-" maxcollen "s ", "")
for (key in columns) {
printf("%-" maxcollen "s ",key)
}
for (id in ids) {
printf("\n%-" maxcollen "s ", id)
for (key in columns) {
printf("%-" maxcollen "s ", col1[id ":::" key])
}
}
printf("\n")
}' myfile.csv
出力：
glkgb tzfl mv abcdef xyz
id3 2 5
id100 4 1 2 1 8
id1 1 2 1 8
id2 1 1 6
==
表示順に列とIDを表示する別のバージョン：
awk '
{
if (colname[$3]!=1) {colname[$3]=1 ; cols[++coln]=$3 }
if (idval[$2]!=1) {idval[$2]=1 ; ids[++idn]=$2 }
col1[$2 ":::" $3]=$1
if (maxcollen< length($1)) maxcollen=length($1)
if (maxcollen< length($2)) maxcollen=length($2)
if (maxcollen< length($3)) maxcollen=length($3)
}
END {
printf("%-" maxcollen "s ", "")
for (i=1; i<=coln ; i++ ) {
printf("%-" maxcollen "s ",cols[i])
}
for (j=1; j<=idn ; j++) {
printf("\n%-" maxcollen "s ", ids[j])
for (i=1; i<=coln ; i++) {
printf("%-" maxcollen "s ", col1[ids[j] ":::" cols[i]])
}
}
printf("\n")
}' myfile.csv
出力：
xyz abcdef mv tzfl glkgb
id1 8 1 2 1
id2 6 1 1
id3 5 2
id100 8 1 2 1 4