☰

区切り文字を使用して列を行に分割

tag-icon • tag-icon text-processing awk
区切り文字を使用して列を行に分割

区切り文字に基づいて分割したい3つの動的列を持つソースファイルがあります。

下の画像は私のソースファイルと希望の出力を示しています。どちらも次のテキストで再現されます。

ソースファイルと期待される出力

源泉：

Emp,Hire,ILT,Mgr,Pi
123,Y,UB|VY,,BY|LN|VB
435,N,LN,HA-12/09/2019|LA-13/09/2019,BY|LN|OR
657,Y,,MA-12/09/2019|RA-13/09/2019,VB

希望の出力：

Emp,hire,ILT,Mgr,Pi
123,Y,UB,,BY
123,Y,VY,,LN
123,Y,,,VB
435,N,LN,HA-12/09/2019,BY
435,N,,LA-13/09/2019,LN
435,N,,,OR
657,Y,,MA-12/09/2019,VB
657,Y,,RA-13/09/2019,VB

ベストアンサー1

このAWKスクリプトを次のように保存するとしますscript。

BEGIN {
                                # Populate an array that lists (is indexed
                                # by) the position of "dynamic" fields.
  split(dynamic,temp,",")
  for (i in temp)
    tosplit[temp[i]] = i
}
{
                                # Determine how many times the current
                                # line will be repeated...
  times = 1
                                # by counting how many times, for each field,
  for (f = 1; f <= NF; f++) {
                                # the "|" separator is replaced by itself.
    repl = gsub(/\|/, "&", $f)
    if ( (repl + 1 ) > times)
      times = (repl + 1 )
  }
                                # For each time the line has to be repeated:
  for (i = 1; i <= times; i++) {
    for (f = 1; f <= NF; f++) {
                                # every "dynamic" field is split on "|", and
                                # only the component which belongs to the
                                # current line repetition is printed;
      if (f in tosplit) {
        split($f, p, "|")
        printf( (f == NF ? "%s"ORS : "%s"OFS), p[i] )
      }
                                # all other fields are printed unchanged.
      else
        printf( (f == NF ? "%s"ORS : "%s"OFS), $f )
    }
  }
}

その後、次のように呼び出すことができます。

awk -v FS=',' -v OFS=',' -v dynamic=3,4,5 -f script source_file

awk分割する必要がある列のインデックス（「動的」フィールド）は、カンマ区切りリストを保持する変数として渡されます。

おすすめ記事