sedは範囲定義パターン内で逆参照を作成できますか？

あなたは正しいです：それでも逆参照は基本正規表現で定義されています。（着替え）（各sedアドレスはBREなので、逆参照をサポートする）、逆参照は他のBREで定義されているキャプチャリンググループを取得できません。したがって、このアドレスのキャプチャグループは/^( *)group foo/他のアドレスから取得できません/^\1\}/。

これはtest.awk、開かれたかっこと閉じたかっこを計算することによって行われます。

brk && /\{/{brk++} #Increment brk if brk is not zero and line contains {
brk && /\}/{brk--} #Decrement brk if brk is not zero and line contains }
/^[[:blank:]]*group foo \{/{brk=1;prt=1} #Set brk and prt if match initial pattern
prt                #Print line if prt is set
!brk && prt{prt=0} #If brk is zero and prt is not, set prt=0

$ cat file
foo bar
        foo bar2
        }
                group foo {
                    command;
                    setting {
                        value;
                    }
                    command;
                }
        dri {
    }
end
$ awk -f test.awk file
                group foo {
                    command;
                    setting {
                        value;
                    }
                    command;
                }

別のあまりエレガントなオプションは、空のスペースを計算することです。これがまさに試みの背景になるアイデアです。インデントにタブがあると壊れます。

/^ *group foo \{/{
    match($0,/^ */) #Sets RLENGTH to the length in characters of the matched string
    i=RLENGTH
}
i                   #If i is set, the current line is printed
i&&/^ *\}$/{
    match($0,/^ */)     #Again, sets RLENGTH to the length of the matched string
    if(RLENGTH==i){i=0} #If the value is equal to the one from group foo line, unset i
}