次の行で利用可能なリスト印刷数を比較してください。

投稿したawkの回答を取ると前の質問「select」行に到達するのではなく、空行またはファイルの終わりに達したときに情報を印刷するように調整します（これを最初に実行する必要がありましたが、怠惰です）。

$ cat tst.awk
BEGIN { FS="[:= ]" }
NF {
    if ( $1 == "Chosen" ) {
        user = $4
        chosen = $5
    }
    else {
        avail[$5]
    }
    next
}
{ prt() }
END {
    prt()
    printf "%d users chose available %d times and not available %d times\n", userCnt, availCnt, notAvailCnt
}

function prt() {
    if ( chosen in avail ) {
        availCnt++
        str = ""
    }
    else {
        notAvailCnt++
        str = " not"
    }
    userCnt++
    printf "User %s chose %s which was%s available\n", user, chosen, str
    delete avail
}

その後、新しい入力に対して実行すると、次のものが生成されます。

$ awk -f tst.awk file
User 75 chose 1655 which was not available
User 10 chose 1301 which was available
User 20 chose 1503 which was available
3 users chose available 2 times and not available 1 times

その後、これを調整してglobalIDを印刷できます。

$ cat tst2.awk
BEGIN { FS="[:= ]" }
NF {
    if ( $1 == "Chosen" ) {
        user = $4
        chosen = $5
    }
    else if ( $1 == "globalID" ) {
        globalID = $2
    }
    else {
        avail[$5]
    }
    next
}
{ prt() }
END {
    prt()
    printf "%d users chose available %d times and not available %d times\n", userCnt, availCnt, notAvailCnt
}

function prt() {
    if ( chosen in avail ) {
        availCnt++
        str = ""
    }
    else {
        notAvailCnt++
        str = " not"
    }
    userCnt++
    printf "User %s chose %s which was%s available, and had globalID %s\n", user, chosen, str, globalID
    delete avail
}

出力：

$ awk -f tst2.awk file
User 75 chose 1655 which was not available, and had globalID 1000
User 10 chose 1301 which was available, and had globalID 1020
User 20 chose 1503 which was available, and had globalID 1030
3 users chose available 2 times and not available 1 times

実際に出力したい内容を印刷するためにステートメントを変更するのがどれほど簡単かを確認してください。print（そしてgrepや他のものにパイプするのではなく、awkで行うのは簡単です）。

$ cat tst3.awk
BEGIN { FS="[:= ]" }
NF {
    if ( $1 == "Chosen" ) {
        user = $4
        chosen = $5
    }
    else if ( $1 == "globalID" ) {
        globalID = $2
    }
    else {
        avail[$5]
    }
    next
}
{ prt() }
END { prt() }

function prt() {
    if ( chosen in avail ) {
        result = "match"
    }
    else {
        result = "nomatch"
    }
    if ( target == result ) {
        print globalID
    }
    delete avail
}

。

$ awk -v target='match' -f tst3.awk file
1020
1030

$ awk -v target='nomatch' -f tst3.awk file
1000