☰

Linuxと一致する相対ログファイルはありますか？

tag-icon • tag-icon awk grep vim logs
Linuxと一致する相対ログファイルはありますか？

grepログファイルの内容を使用または一致させる方法は既にわかっていますが、awk次のことを行う方法はありますか？

  1. ファイルの特定の行を一致させ、結果に含めます。
  2. ファイル（1.）の一致する行から始まり、2番目の文字列が一致するまで上向きに検索し、その文字列とその間のすべての行を結果に含めます。
  3. 次に、3番目の一致を使用して一致（1.）から始めて3番目の文字列を一致させ、その文字列と結果の間のすべての行を含めて検索します。

これにより、検索したいコンテンツがBEGINNINGおよびENDコンテキストにある場合、検索したいコンテンツが発生したコンテキストのみを検索できます。ログファイルは次のとおりです。

<several-1000-lines>
...[BEGINX]
some log a
<several-1000-lines>
...[First-string-i-search-for]
<several-1000-lines>
some log b
...[ENDX]
<several-1000-lines>

その後、検索すると次の結果が表示されます[First-string-i-search-for]。

...[BEGINX]
some log a
<several-1000-lines>
...[First-string-i-search-for]
<several-1000-lines>
some log b
...[ENDX]

ベストアンサー1

$ cat tst.awk
BEGIN {
    beg = "[BEGINX]"
    mid = "[First-string-i-search-for]"
    end = "[ENDX]"
}
index($0,beg) {
    gotBeg = 1
    gotMid = 0
    buf = ""
}
gotBeg {
    buf = buf $0 ORS
    if ( index($0,mid) ) {
        gotMid = 1
    }
    if ( index($0,end) ) {
        if ( gotMid ) {
            printf "%s", buf
        }
        gotBeg = 0
    }
}


$ awk -f tst.awk file
...[BEGINX]
some log a
<several-1000-lines>
...[First-string-i-search-for]
<several-1000-lines>
some log b
...[ENDX]

上記の仮定は次のとおりです。

  1. 検索中の3つの文字列は常に異なる行に表示されます。
  2. いつも最後のBEGINXからその後の最初のENDXまでテストしたいと思います。

おすすめ記事