インストールするマウントポイントに必要なマウントポイントをどのように自動的にインストールしますか？

Question

具体的には、FS 全体ではなく FS の「home」サブディレクトリLABEL=XYZをにマウントする場合は、次の行を追加できます。/newplace/mypath

LABEL=XYZ /newplace subdir subdir=main,srctype=vfat,noauto,... 0 0

そして、次のスクリプトで/sbin/mount.subdirヘルパー（直接意味せずに呼び出される）を作成します。mount /newplace

#! /bin/zsh -p
(( EUID == 0 )) || exec sudo -- "$0" "$@"
PATH=/bin:/sbin:/usr/bin:/usr/sbin

# mount -t subdir -o subdir=foo -o otheroption source /dest calls us
# as mount.subdir source /dest -o rw,subdir=foo,otheroption
dev=${1?} dest=${2?} opts=( ${(s[,])4?} )

# extract mandatory subdir option
(( i = $opts[(I)subdir=*] )) || exit
subdir=${opts[i]#*=}
opts[i]=()

# extract optional srctype option
if (( i = $opts[(I)srctype=*] )); then
  type=(-t "$opts[i]")
  opts[i]=()
else
  type=()
fi

tmpdir=$(mktemp -d) || exit

mounted()true
if
  mount "$type[@]" -o "${(j[,])opts}" -- "$dev" "$tmpdir"
then
  mount --bind -- "$tmpdir/$subdir" "$dest" || mounted()false
  umount -- "$tmpdir"
fi && rmdir -- "$tmpdir" && mounted

FS全体をtmpdirにマウントし、サブディレクトリをターゲットの場所にバインドしてマウントし、tmpdirをアンマウントして削除します。

今後の編集で明確に説明したように、実際にマウントしたいと思っており、サブ/newplaceディレクトリにFSをマウントしたいという最終目標に向かう中間ステップではなく、同様のアプローチをとることができます。必要なファイルシステムをマウントするヘルパープログラム：/mypath/mypath/myplace

LABEL=XYZ /mypath vfat noauto,[...]
/myplace/main /newplace prereq prereq=/myplace,noauto,... 0 0

/sbin/mount.prereq次のスクリプトでヘルパーを作成します。

#! /bin/zsh -p
(( EUID == 0 )) || exec sudo -- "$0" "$@"
PATH=/bin:/sbin:/usr/bin:/usr/sbin

src=${1?} dst=${2?} opts=( ${(s[,])4?} )

# extract prereq options
for prereq in ${(M)opts:#prereq=*}; do
  prereq=${prereq#*=}
  mountpoint -q -- $prereq ||
    mount -- $prereq ||
    exit
done
opts=(${opts:#prereq=*})

exec mount --bind -o "${(j[,])opts}" -- "$src" "$dst"

を削除した/mypath後は自動的に削除されません。/newplace

POSIXシェルと同じ構文（それでも動作するはずですbash）は次のとおりです。

#! /bin/sh -
[ "$(id -u)" -eq 0 ] || exec sudo -- "$0" "$@"
PATH=/bin:/sbin:/usr/bin:/usr/sbin

src="${1?}" dst="${2?}"

set -o noglob
IFS=,
set -- ${4?}

# extract prereq options
for opt do
  case $opt in
    (prereq=*)
      prereq=${opt#*=}
      mountpoint -q -- "$prereq" ||
        mount -- "$prereq" ||
        exit
      ;;
    (*)
      set -- "$@" "$opt"
  esac
  shift
done
opts="$*"

exec mount --bind -o "$opts" -- "$src" "$dst"

（検証されていません）。

できないなら編集するスクリプトを計測できます。たとえば、次のように作成すると、次bashのように呼び出されます。

bash -c '
  mount() {
    if [[ $1 = "/newplace" ]]; then
      command mount /mypath || return
    fi
    command mount "$@"
  }
  export -f mount
  exec "$0" "$@"' your-script its args

またはに書かれている場合は、zsh以下を追加~/.zshenv（またはそのスクリプトに設定/some/dir/.zshenv）します。ZDOTDIR=/some/dir

if [[ $ZSH_SCRIPT:P = /path/to/your-script ]]; then
  mount() {
    if [[ $1 = /newplace ]]; then
      command mount /mypath || return
    fi
    command mount "$@"
  }
fi

または、すべてのシェルに対して同じ操作を実行するスクリプトを追加しますmount。/some/dir

#! /bin/sh -
if [ "$1" = /newplace ]; then
  /bin/mount /mypath || exit
fi
exec /bin/mount "$@"

スクリプトを呼び出します。

PATH="/some/dir:$PATH" your-script its args

Answer 1