☰

共有要素（bash / awk）に基づいて行をマージする

tag-icon • tag-icon bash awk scripting
共有要素（bash / awk）に基づいて行をマージする

次のファイルがあります。

a3 v2c
v5 a7
a9 v2c
v1c a3 a7c

希望の出力（各行に重複なし）：

a3 a7c a9 v1c v2c
a7 v5

私が望むのは、少なくとも1つの要素を共有する行をマージすることです。行2では、両方の要素が一意であり、行はそのまま（並べ替えられた順序で）出力されます。 1行目は、「v2c」を3行目と共有し、「a3」を4行目と共有するため、これら3つの行が結合してソートされます。共有要素は別の列に存在できます。

大容量ファイル（200,000行）の場合、コードは非常に遅くなります。

Lines=$(awk 'END {print NR}' $1)
bank=$1
while [ $Lines -ge 1 ]
    do
        echo "Processing line $Lines"
        awk -v line=$Lines 'NR == line' $bank | awk NF=NF RS= OFS="\n" | sort | uniq > Query.$Lines
        k=0
    while [[ $k != 1 ]]
        do
                if [[ $k != "" ]]
                    then
                        grep -f Query.$Lines $bank | awk '{gsub(/\t/,"\n")}1' | awk '{gsub(/ /,"\n")}1' | sort | uniq > Query1.$Lines
                        grep -f Query1.$Lines $bank | awk '{gsub(/\t/,"\n")}1' | awk '{gsub(/ /,"\n")}1' | sort | uniq > Query2.$Lines
                        grep -f Query2.$Lines $bank | awk '{gsub(/\t/,"\n")}1' | awk '{gsub(/ /,"\n")}1' | sort | uniq > Query3.$Lines
                        k=$(diff Query2.$Lines Query3.$Lines)
                            if [[ $k != "" ]]
                                then mv Query3.$Lines Query.$Lines
                            fi
                    else
                        awk NF=NF RS= OFS=" " Query3.$Lines >> $1.output.clusters
                        grep -v -f Query3.$Lines $bank > NotFound.$Lines
                        bank=NotFound.$Lines
                        k=1
                fi
    done
rm Query*
        Lines=$(( $Lines - 1 ))
done
exit
find . -maxdepth 1 -type f -size 0 -delete
rm NotFound.* Query.* Query1.* Query2.* Query3.*

私はbashやawkを使うよりシンプルで効率的なソリューションがあると思います。よろしくお願いします！

ベストアンサー1

配列の配列合計にGNU awkを使用するsorted_in：

$ cat tst.awk
{
    for ( fldNrA=1; fldNrA<NF; fldNrA++ ) {
        fldValA = $fldNrA
        for ( fldNrB=fldNrA+1; fldNrB<=NF; fldNrB++ ) {
            fldValB = $fldNrB
            val_pairs[fldValA][fldValB]
            val_pairs[fldValB][fldValA]
        }
    }
}

function descend(fldValA,       fldValB) {
    if ( !seen[fldValA]++ ) {
        all_vals[fldValA]
        for ( fldValB in val_pairs[fldValA] ) {
            descend(fldValB)
        }
    }
}

END {
    PROCINFO["sorted_in"] = "@ind_str_asc"
    for ( fldValA in val_pairs ) {
        delete all_vals
        descend(fldValA)
        if ( fldValA in all_vals ) {
            sep = ""
            for ( fldValB in all_vals ) {
                printf "%s%s", sep, fldValB
                sep = OFS
            }
            print ""
        }
    }
}


$ awk -f tst.awk file
a3 a7c a9 v1c v2c
a7 v5

元の答え：

これはスタート配列の配列にGNU awkを使用する：

$ cat tst.awk
{
    for ( fldNr=1; fldNr<=NF; fldNr++ ) {
        fldVal = $fldNr
        fldVals_rowNrs[fldVal][NR]
        rowNrs_fldVals[NR][fldVal]
    }
}
END {
    for ( rowNr=1; rowNr<=NR; rowNr++ ) {
        noOverlap[rowNr]
    }

    for ( rowNrA in rowNrs_fldVals ) {
        for ( fldVal in rowNrs_fldVals[rowNrA] ) {
            for ( rowNrB in fldVals_rowNrs[fldVal] ) {
                if ( rowNrB > rowNrA ) {
                    overlap[rowNrA][rowNrB]
                    delete noOverlap[rowNrA]
                    delete noOverlap[rowNrB]
                }
            }
        }
    }

    for ( rowNrA in overlap ) {
        for ( rowNrB in overlap[rowNrA] ) {
            print "Values overlap between lines:", rowNrA, rowNrB
        }
    }

    for ( rowNr in noOverlap ) {
        print "All unique values in line:", rowNr
    }
}


$ awk -f tst.awk file
Values overlap between lines: 1 3
Values overlap between lines: 1 4
All unique values in line: 2

print "Values overlap between lines:", rowNrA, rowNrBそこで私は行を呼び出して、値が重なるすべての行間のすべての共通値を見つけ、次のように特定の順序PROCINFO["sorted_in"]で印刷する（再帰下降？）関数を実装する必要があると思います。 。

再帰関数に関する情報を問い合わせたのでコメントから以下は、さまざまな目的で使用される再帰 awk 関数の例です (すべての関数には名前が付けられますが、descend()名前は重要ではありません)。

この操作で、これらの関数を書く方法についてのアイデアを得ることができることを願っています。

おすすめ記事