XSLT がデフォルトですべてのテキストを出力するのはなぜですか? 質問する

前のコードではなぜTEXTが出力されるのでしょうか。なぜXSLに他のすべてのテキストを無視するように要求する必要があるのでしょうか。これはすべてのXMLパーサーの動作ですか、それとも私の独自の動作ですか。

仕様書に規定されている最も基本的なXSLT機能の1つを発見しました。XSLTの組み込みテンプレート。

からスペック:

スタイルシート内の明示的なテンプレート ルールによってパターン マッチが成功しない場合でも再帰処理を続行できるようにする組み込みテンプレート ルールがあります。このテンプレート ルールは、要素ノードとルート ノードの両方に適用されます。次に、組み込みテンプレート ルールと同等のものを示します。

<xsl:template match="*|/">
  <xsl:apply-templates/>
</xsl:template>

各モードには組み込みテンプレート ルールもあり、これにより、スタイルシート内の明示的なテンプレート ルールによるパターン マッチが成功しない場合でも、同じモードで再帰処理を続行できます。このテンプレート ルールは、要素ノードとルート ノードの両方に適用されます。次に、モード m の組み込みテンプレート ルールと同等のものを示します。

<xsl:template match="*|/" mode="m">
  <xsl:apply-templates mode="m"/>
</xsl:template>

テキストおよび属性ノード用の組み込みテンプレート ルールもあり、テキストを次のようにコピーします。

<xsl:template match="text()|@*">
  <xsl:value-of select="."/>
</xsl:template>

処理命令とコメントの組み込みテンプレート ルールは、何もしないことです。

<xsl:template match="processing-instruction()|comment()"/>

名前空間ノードの組み込みテンプレート ルールも何も行いません。名前空間ノードに一致するパターンは存在しないため、組み込みテンプレート ルールは名前空間ノードに適用される唯一のテンプレート ルールです。

組み込みテンプレート ルールは、スタイルシートの前に暗黙的にインポートされたかのように扱われるため、他のすべてのテンプレート ルールよりもインポートの優先順位が低くなります。したがって、作成者は明示的なテンプレート ルールを含めることで組み込みテンプレート ルールをオーバーライドできます。

<a>
  <b>
    <c>Don't want to see this</c>
  </b>
</a>

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>
 
 <xsl:template match="a|b">
   <xsl:copy>
      <xsl:attribute name="name">
        <xsl:value-of select="name()"/>
      </xsl:attribute>
      <xsl:apply-templates/>
   </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

<a name="a">
   <b name="b">Don't want to see this</b>
</a>

 <xsl:template match="*">
  <xsl:message terminate="no">
   WARNING: Unmatched element: <xsl:value-of select="name()"/>
  </xsl:message>
  
  <xsl:apply-templates/>
 </xsl:template>

 WARNING: Unmatched element: c