tail -0fを使用してLinux / AIXで複数のファイルを追跡する方法

何について：

tail -f file1 & tail -f file2

または各行にファイル名を付けます。

tail -f file1 | sed 's/^/file1: /' &
tail -f file2 | sed 's/^/file2: /'

名前がパターンと一致するすべてのファイルを追跡するには、tail -f次のスクリプトを使用してこれを実行できます（毎秒ファイルから継続的に読み取ります）zsh。

#! /bin/zsh -
zmodload zsh/stat
zmodload zsh/zselect
zmodload zsh/system
set -o extendedglob

typeset -A tracked
typeset -F SECONDS=0

pattern=${1?}; shift

drain() {
  while sysread -s 65536 -i $1 -o 1; do
    continue
  done
}

for ((t = 1; ; t++)); do
  typeset -A still_there
  still_there=()
  for file in $^@/$~pattern(#q-.NoN); do
    stat -H stat -- $file || continue
    inode=$stat[device]:$stat[inode]
    if
      (($+tracked[$inode])) ||
        { exec {fd}< $file && tracked[$inode]=$fd; }
    then
      still_there[$inode]=
    fi
  done
  for inode fd in ${(kv)tracked}; do
    drain $fd
    if ! (($+still_there[$inode])); then
      exec {fd}<&-
      unset "tracked[$inode]"
    fi
  done
  ((t <= SECONDS)) || zselect -t $((((t - SECONDS) * 100) | 0))
done

たとえば、現在のディレクトリのすべてのテキストファイルを再帰的に追跡するには、次のようにします。

that-script '**/*.txt' .