この醜い結果をどのように美しく便利なデータに変えますか?
出力:
/* ---------- TA#box#AbC_p ---------- */
insert_job: TA#box#AbC_p job_type: a
#owner: bob
permission: gx
date_conditions: 1
days_of_week: su
start_times: "16:15"
run_window: "16:15-17:30"
description: "Job AbC that runs at 4:15PM on Sundays, and should end before 5:30PM"
/* ---------- TA#cmd#EfGJob_p ---------- */
insert_job: TA#cmd#EfGJob_p job_type: b
box_name: TA#box#AbC_p
command: /path/to/shell/script.sh
machine: vm_machine1
#owner: alex
permission: gx
date_conditions: 2
run_window: "16:20-16:30"
description: "job EfG that runs within box AbC"
term_run_time: 60
std_out: /path/to/log.log
std_err: /path/to/err.log
alarm_if_fail: 1
profile: /path/to/profile
ちょっと待ってください。 #cmd# ジョブは時々 #box# の下に置かれます。 #cmd# セクションは #box# の下にあるとインデントされます。
私の理想的な出力は次のとおりです。
"Job Name", "Time", "Schedule", "Machine", "Description", "Command"
"TA#box#AbC_p", "16:15", "su", "", "Job AbC that runs at 4:15PM on Sundays, and should end before 5:30PM", ""
"TA#cmd#EfGJob_p", "16:15", "su", "vm_machine1", "job EfG that runs within box AbC", "/path/to/shell/script.sh"
私はawk、perl、およびgrepを試していますが、CSV行を印刷する前に「セクション」に関するすべての情報を一緒に取得することはできません。
ベストアンサー1
少し怖いsed oneliner:
sed -n \
# we divide out incoming text to small parts,
# each one as you mentioned from /---.*box.*/ to /profile/
'/---.*box.*/,/profile/{
# inside of each part we do following things:
# if string matches our pattern we extract
# the value and give it some identifier (which you
# can see is "ij", "st" and so on)
# and we copy that value with identifier to hold buffer,
# but we don't replace the content of hold buffer
# we just append (capital H) new var to it
/insert_job/{s/[^:]*: /ij"/;s/ .*/",/;H};
/start_times/{s/[^:]*: /st/;s/$/,/;H};
/days_of_week/{s/[^:]*: /dw"/;s/$/",/;H};
/machine/{s/[^:]*: /ma"/;s/$/",/;H};
/description/{s/[^:]*: /de/;s/$/,/;H};
/command/{s/[^:]*: /co"/;s/$/",/;H};
# when line matches next pattern (profile)
# we think that it is the end of our part,
# therefore we delete the whole line (s/.*//;)
# and exchange the pattern and hold buffers (x;)
# so now in pattern buffer we have several strings with all needed variables
# but all of them are in pattern space, therefore we can remove
# all newlines symbols (s/\n//g;). so it is just one string
# with a list of variables
# and we just need to move to the order we want,
# so in this section we do it with several s commands.
# after that we print the result (p)
/profile/{s/.*//;x;s/\n//g;s/ij\("[^"]*box[^"]*",\)/\1/;
s/,\(.*\)st\("[^"]*",\)\(.*ij"[^"]*",\)/,\2\1\3\2/;
s/\([^,]*,[^,]*,\)\(.*\)dw\("[^"]*",\)\(.*ij"[^"]*",[^,]*,\)/\1\3\2\4\3/;
s/de/"",/;s/ij/""\n/;
s/\(\n[^,]*,[^,]*,[^,]*,\)\(.*\)ma\("[^"]*",\)/\1\3\2/;
s/co\("[^"]*"\),\(.*\)/\2\1/;s/de//;p}
};
# the last command just adds table caption and nothing more.
# note: if you want to add some new commands,
# add them before this one
1i"Job Name", "Time", "Schedule", "Machine", "Description", "Command"'
フィールドの順序はボックスごとに異なる可能性があるため作成しましたが、プロファイルは常に最後です。順番が常に同じであれば簡単になります。