lsof：ソケットfdのI / O速度を測定します。

使用を検討してくださいシステムクリック。 DTraceクローンですが、Linuxの場合は、カーネルを動的にパッチするカーネルモジュールをコンパイルし、そのデータへのフルアクセス権を持ちます（したがって、lsofこの場合は必要ありません）。

しかし、より多くの情報を要求するほど、スクリプトは難しくなり、カーネルのバージョンによって異なります。

たとえば、ソケットの単純な統計的類似ユーティリティは次のとおりです。

global stats;

probe begin {
    printf("%14s %6s %12s %5s %5s %8s\n", "NAME", "PID", "EXECNAME",
                "INO", "OPS/S", "BYTES");
}

function file_ino:long (file:long)
{
    if(file == 0) return -1;
    d_inode = @cast(file, "file", "kernel")->f_inode;
    if (d_inode == 0) return -1;
    return @cast(d_inode, "inode", "kernel")->i_ino;
}

probe socket.send, socket.receive {
    if(success == 0) next;

    /* Get inode number for a socket. Depending on 
       operation, struct file is contained in different fields. 
       Determine that field and get inode number */
    ino = -1;
    if(@defined($sock)) {
        ino = file_ino($sock->file);
    }
    else if(@defined($iocb)) {
        ino = file_ino($iocb->ki_filp);
    }

    stats[pid(), execname(), ino, name] <<< size;
}

probe timer.s(1) {
    /* Every 1 second print statistics */
    foreach([pid+, ename, ino, name] in stats) {
        printf("%14s %6d %12s %5d %5d %8d\n", name, pid, ename, ino, 
                    @count(stats[pid, ename, ino, name]), 
                    @sum(stats[pid, ename, ino, name]));
    }
    delete stats;
}

バニラLinux 3.12でテストしましたが、ご覧のとおり、inode番号を取得するロジックは内部カーネル構造に依存しています。

ご覧のとおり、ほとんどの場合、SSHセッションへの書き込みを追跡します。

       NAME    PID     EXECNAME   INO OPS/S    BYTES
socket.send   2655         sshd  7480     1       96
socket.send   2655         sshd  7480     1       96
socket.send   2655         sshd  7480     1       96
...

例には、より複雑なスクリプトがあります。https://sourceware.org/systemtap/examples/network/socktop

警告する

SystemTapは開発中のカーネルレベルのソフトウェアなので、カーネルがクラッシュしたり停止したりする可能性があります。このような場合はまれですが注意してください。

引用する

• https://sourceware.org/systemtap/- プロジェクトホームページ
• https://sourceware.org/systemtap/wiki- ウィキペディア
• https://sourceware.org/systemtap/tapsets/socket.stp.html- デモスクリプトで使用されているソケットタブセット
• https://sourceware.org/systemtap/langref/- SystemTap言語リファレンス