☰

一致および不一致グループ数の計算基準

tag-icon • tag-icon bash shell-script sed awk perl
一致および不一致グループ数の計算基準

次のシェルスクリプトを書くのに役立ちます。サンプル（col2）の各レーン（col1）で一貫した変数の数を計算する必要があります。たとえば、Lane1変数1（col4）のすべての値は3つのサンプルすべてのサンプルであるため、Variable1は一貫性変数として計算されます。同様に、レーン2の変数2と3は一致しません。

lane1  sample1 variable1 ab
lane1  sample2 variable1 ab
lane1  sample3 variable1 ab   


lane1  sample1 variable2 cd
lane1  sample2 variable2 cd
lane1  sample3 variable2 cd

lane1  sample1 variable3 gh
lane1  sample2 variable3 ab
lane1  sample3 variable3 gh

lane2  sample1 variable1 ac
lane2  sample2 variable1 ac
lane2  sample3 variable1 ac


lane2  sample1 variable2 gt
lane2  sample2 variable2 gt
lane2  sample3 variable2 ac

lane2  sample1 variable3 ga
lane2  sample2 variable3 ga
lane2  sample3 variable3 ac

出力

3つのサンプルすべてで一貫性のある変数と一貫性のない変数の数

      #Consistent #Inconsistent
lane1  2             1
lane2  1             2

ベストアンサー1

Perlソリューション：

#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

my %values;
while (<>) {
    next if /^$/; # Skip empty lines
    my ($lane, $sample, $var, $val) = split;
    die "Duplicate $lane $sample $var\n" if $values{$lane}{$var}{$val}{$sample};
    $values{$lane}{$var}{$val}{$sample} = 1;
}

my %results;
for my $lane (keys %values) {
    for my $var (keys %{ $values{$lane} }) {
        my $count = keys %{ $values{$lane}{$var} };
        if (1 == $count) {
            ++$results{$lane}{consistent};
        } else {
            ++$results{$lane}{inconsistent};
        }
    }
    say join "\t", $lane, @{ $results{$lane} }{qw{ consistent inconsistent }};
}

おすすめ記事