☰

2つの異なるファイルの2つの列を比較します。

tag-icon • tag-icon text-processing files awk scripting merge
2つの異なるファイルの2つの列を比較します。

最初の列に基づいて2つのファイルの間で2番目と3番目の列を減算し、diff_column_2（DIFF-IO）= diff_column_3（DIFF-SELECT）= 0の行を表示しないでください。両方のファイルに存在し、出力でENDに残る必要がある最後の行を除いて、順序はランダムに指定できます。

これref_file：

    testing 20 10
    jobs 15 20
    issues 0 1
    work 15 25
    Total 50 56

これhead_file：

    testing 20 10
    jobs 15 30
    work 12 25
    games 1 2
    Total 48 67

希望の出力：

TABLE,REF-IO,HEAD-IO,DIFF-IO,REF-SELECT,HEAD-SELECT,DIFF-SELECT
jobs,15,15,0,20,30,-10
work,15,12,3,25,25,0
games,0,1,-1,0,2,-2
issues,0,0,0,1,0,1
Total,50,48,2,56,67,-11

ベストアンサー1

awk '
    BEGIN {
        print "TABLE,REF-IO,HEAD-IO,DIFF-IO,REF-SELECT,HEAD-SELECT,DIFF-SELECT"
        OFS = ", "
    }
    FNR==NR {
        A[$1]=$2
        B[$1]=$3
        next
    }
    {
        if (!($1 in A)) {
            A[$1] = B[$1] = 0
        }
        diff_io = $2 - A[$1]
        diff_sel= $3 - B[$1]
        C[$1] = 1
    }
    diff_io || diff_sel {
        if (first) {
            print line
        }
        first = 1
        line = $1 OFS $2 OFS A[$1] OFS diff_io OFS $3 OFS B[$1] OFS diff_sel
    }
    END {
        for (name in A) {
            if (!(name in C)) {
                print name, 0, A[name], -A[name], 0, B[name], -B[name]
            }
        }
        print line
    }
    ' head_file ref_file

簡単に入力するには、次の操作を実行できますjoin。

join -a1 -a2 -e0 <(sort head_file) <(sort ref_file) -o0,1.2,2.2,0,1.3,2.3 |
awk '
    BEGIN {
        print "TABLE,REF-IO,HEAD-IO,DIFF-IO,REF-SELECT,HEAD-SELECT,DIFF-SELECT"
        OFS = ", "
    }
    {
        $4=$2-$3
        $7=$5-$6
    }
    /Total/ {
        end=$0
        next
    }
    $4!=0 || $7!=0;
    END {
        print end
    }'

おすすめ記事