一連の新しいファイルを生成するためにawkを使用して2つのファイル間の算術

Question

TL;博士:awkあなたの例のためにハードコードされた圧縮スクリプト

NR != FNR {
    out = "out" FNR ".txt"
    printf "" > out
    for (l=m=1; l <= nl; l++)
        printf tmpl[l] ORS, l in vals ? $(m++)*vals[l] : 0 >> out
    close(out)
    next
}

{
    gsub(/%/, "%%")
# here is the regex that selects the fields by their name
    if ($3 ~ /^(vox_la_max|knockout_max|shed_prob)[^[:alnum:]_]*$/) {
        vals[NR] = $1
        sub(/^[0-9]+(\.[0-9]+)?/, OFMT)
    }
    tmpl[NR] = $0; nl++
}

次のように使用してください。

LC_NUMERIC=C awk -f script input.txt multipliers.txt

という出力ファイルが生成されますoutX.txt。

LC_NUMERIC=Cこのビットは、ロケール内の浮動小数点値の小数点区切りとしてドットの代わりにコンマを使用する場合に必要です。

単純化のために合理的に見えるいくつかの仮定を確立しました。

必須入力フィールドは、常にフィールド名が1つの単語であり、スペース（少なくとも1つのスペース）で区切る必要があることを示すコメントが隣接する別々の値です。/*
同じ名前のフィールドはありません。
浮動小数点値は、数値と (おそらく) 点で表現されます。つまり、指数や他の科学的表現は使用しません。

上記と同じですが、以下を可能にするために詳細、説明、拡張されました。

行番号別に必須項目を任意に指定
各フィールドに属する入力行のコメントとして参照される名前で、必須フィールドをランダムに指定します。
出力ファイルは拡張子（例：.txt）を持つことができる入力ファイル名に沿って自動的に名前が付けられ、表示されるパス（存在する場合）は次のようになります。いいえつまり、入力ファイルが含まれているディレクトリでスクリプトを実行することをお勧めします。

# some preparations
BEGIN {
    # output files named as the input file name
    split(ARGV[1], f, ".")
    outpfx = f[1]
    # remember wanted fields specified on command line as comma-separated line numbers
    if (nums) {
        # split variable "nums" on comma into helper array "r"
        n = split(nums, r, ",")
        # loop over helper array to build final array, thus indexed by wanted line numbers
        while (n) rows[r[n--]]
    }
}

# here we operate on multipliers file
NR != FNR {
    # output file name for this set of multipliers
    out = outpfx FNR ".txt"
    # create/overwrite this output file
    printf "" > out
    # loop over template lines scanned from input file
    for (linenum = multnum = 1; linenum <= numlines; linenum++)
        # use the template line as printf format string to consume values to be multiplied (if any)
        printf tmpl[linenum] ORS, linenum in wanted_values ? $(multnum++)*wanted_values[linenum] : 0 >> out
    close(out)
    next
}

# here we scan the input file to build a template for printf
{
    # escape existing % chars as we are going to leverage printfs own format string which is %-based
    gsub(/%/, "%%")
    # on specified line numbers or named fields:
    if (NR in rows || names && match($3, "^("names")[^[:alnum:]_]*$")) {
        # remember this value
        wanted_values[NR] = $1
        # replace the original value with the printfs conversion specification for floating-point values
        # it will be used by printf later on while processing the multipliers file
        sub(/^[0-9]+(\.[0-9]+)?/, OFMT)
    }
    # remember this whole line as a template
    tmpl[NR] = $0; numlines++
}

次のように使用してください。

# specify fields by their line numbers, each separated by a comma
LC_NUMERIC=C awk -f script -v nums=36,38,39 input.txt multipliers.txt
# or specify fields by their names, each separated by the | character (NOTE it's a regexp)
LC_NUMERIC=C awk -f script -v names='vox_la_max|knockout_max|shed_prob' input.txt multipliers.txt
# or also use both ways of specifying fields
LC_NUMERIC=C awk -f script -v nums=15,112,234,71,5 -v names='vox_la_max|numesp' input.txt multipliers.txt

乗数よりも多くのフィールドが指定されている場合、超過フィールドは0（0を掛けます）になります。

乗数よりも少ないフィールドを指定すると、超過乗数は無視されます。

いずれにせよ、フィールドは常に表示された行番号順に乗数を使用します。つまり、入力ファイルで見つかった最初のフィールドは、そのフィールドの指定方法に関係なく、最初の乗数を使用します。

Answer 1

TL;博士:awkあなたの例のためにハードコードされた圧縮スクリプト

NR != FNR {
    out = "out" FNR ".txt"
    printf "" > out
    for (l=m=1; l <= nl; l++)
        printf tmpl[l] ORS, l in vals ? $(m++)*vals[l] : 0 >> out
    close(out)
    next
}

{
    gsub(/%/, "%%")
# here is the regex that selects the fields by their name
    if ($3 ~ /^(vox_la_max|knockout_max|shed_prob)[^[:alnum:]_]*$/) {
        vals[NR] = $1
        sub(/^[0-9]+(\.[0-9]+)?/, OFMT)
    }
    tmpl[NR] = $0; nl++
}

次のように使用してください。

LC_NUMERIC=C awk -f script input.txt multipliers.txt

という出力ファイルが生成されますoutX.txt。

LC_NUMERIC=Cこのビットは、ロケール内の浮動小数点値の小数点区切りとしてドットの代わりにコンマを使用する場合に必要です。

単純化のために合理的に見えるいくつかの仮定を確立しました。

必須入力フィールドは、常にフィールド名が1つの単語であり、スペース（少なくとも1つのスペース）で区切る必要があることを示すコメントが隣接する別々の値です。/*
同じ名前のフィールドはありません。
浮動小数点値は、数値と (おそらく) 点で表現されます。つまり、指数や他の科学的表現は使用しません。

上記と同じですが、以下を可能にするために詳細、説明、拡張されました。

行番号別に必須項目を任意に指定
各フィールドに属する入力行のコメントとして参照される名前で、必須フィールドをランダムに指定します。
出力ファイルは拡張子（例：.txt）を持つことができる入力ファイル名に沿って自動的に名前が付けられ、表示されるパス（存在する場合）は次のようになります。いいえつまり、入力ファイルが含まれているディレクトリでスクリプトを実行することをお勧めします。

# some preparations
BEGIN {
    # output files named as the input file name
    split(ARGV[1], f, ".")
    outpfx = f[1]
    # remember wanted fields specified on command line as comma-separated line numbers
    if (nums) {
        # split variable "nums" on comma into helper array "r"
        n = split(nums, r, ",")
        # loop over helper array to build final array, thus indexed by wanted line numbers
        while (n) rows[r[n--]]
    }
}

# here we operate on multipliers file
NR != FNR {
    # output file name for this set of multipliers
    out = outpfx FNR ".txt"
    # create/overwrite this output file
    printf "" > out
    # loop over template lines scanned from input file
    for (linenum = multnum = 1; linenum <= numlines; linenum++)
        # use the template line as printf format string to consume values to be multiplied (if any)
        printf tmpl[linenum] ORS, linenum in wanted_values ? $(multnum++)*wanted_values[linenum] : 0 >> out
    close(out)
    next
}

# here we scan the input file to build a template for printf
{
    # escape existing % chars as we are going to leverage printfs own format string which is %-based
    gsub(/%/, "%%")
    # on specified line numbers or named fields:
    if (NR in rows || names && match($3, "^("names")[^[:alnum:]_]*$")) {
        # remember this value
        wanted_values[NR] = $1
        # replace the original value with the printfs conversion specification for floating-point values
        # it will be used by printf later on while processing the multipliers file
        sub(/^[0-9]+(\.[0-9]+)?/, OFMT)
    }
    # remember this whole line as a template
    tmpl[NR] = $0; numlines++
}

次のように使用してください。

# specify fields by their line numbers, each separated by a comma
LC_NUMERIC=C awk -f script -v nums=36,38,39 input.txt multipliers.txt
# or specify fields by their names, each separated by the | character (NOTE it's a regexp)
LC_NUMERIC=C awk -f script -v names='vox_la_max|knockout_max|shed_prob' input.txt multipliers.txt
# or also use both ways of specifying fields
LC_NUMERIC=C awk -f script -v nums=15,112,234,71,5 -v names='vox_la_max|numesp' input.txt multipliers.txt

乗数よりも多くのフィールドが指定されている場合、超過フィールドは0（0を掛けます）になります。

乗数よりも少ないフィールドを指定すると、超過乗数は無視されます。

いずれにせよ、フィールドは常に表示された行番号順に乗数を使用します。つまり、入力ファイルで見つかった最初のフィールドは、そのフィールドの指定方法に関係なく、最初の乗数を使用します。

一連の新しいファイルを生成するためにawkを使用して2つのファイル間の算術

ベストアンサー1

おすすめ記事