固定幅ファイルを解析し、Oracle Dbに基づいて解析された値を見つけます。

開始点として以下のスクリプトを試してみてください。

awkところで、どのタイプのUNIXを実行しているのか、どのシェルを使用しているのか、どのバージョンを使用しているのかは明らかではありませんでした。私はあなたがLinux（またはGNUコアユーティリティがインストールされている他のシステム）、bash、およびGNU awkを実行していると仮定します。しかも情報圧縮。unzipこれらの仮定が間違っている場合は、システムに合わせてbash + awkスクリプトを調整する必要があります。

$ cat process-zip-files.sh 
#!/bin/bash

# create a temporary directory
# mktemp is in GNU coreutils
td="$(mktemp -d)"

for zf in *.zip; do
  # unzip options: -qq = very quiet, -o = don't prompt for overwrite,
  # -d = directory to unzip files into.
  unzip -qq -o -d "$td" "$zf" '*.[0-9][0-9][0-9]'
done

# Process each unzipped text file individually
# This awk script requires GNU awk.  The ENDFILE pattern
# is a GNU extension to awk.
awk '/^999 / { data[i++] = substr($0,20,34) };

     ENDFILE {
       out="";
       for (i in data) { out = out data[i] "," };
       sub(/,$/,"",out);
       print "(" out ")";
       delete data;
     }' "$td/"*

# delete the temporary directory and everything in it
rm -rf "$td/"

999このスクリプトは、各テキストファイルに少なくとも1つのレコードがあると仮定します。そうでない場合は、配列のENDFILEブロックに1つ以上の要素があることを確認する必要があります。それ以外の場合は、そのテキストファイルに対して1行だけ出力されますdata。()

これは、エラーの確認や処理を行わず、例外や複雑な状況を処理しようとしない最小限のスクリプトです。

出力例（例テキストを含むzipファイルを作成した後）：

$ ./process-zip-files.sh 
(123456789012345,234567890123456)

より良いスクリプトはを使用することですperl。これにより、Oracleデータベースへの接続が確立されます（openを使用して）。データベースインタフェースそしてDBD::Oracle。

次に、今日のzipファイルのバッチを開きます（次を使用）。アーカイブ::郵便番号モジュール）とその中の各.NNNテキストファイルを処理します。テキストファイルのデータを使用してSQL文を構成し、それをOracle DBに送信します。

ステートメントは、検索、挿入、更新、削除など、通常SQLを使用して実行できるすべての操作です。

pythonもう一つの良い実装言語になります。 Oracleなどのデータベースやzipファイルと対話するためのライブラリモジュールもあります。

そこはいBashや他のシェルからOracleや他のSQLデータベースと直接対話する方法があります。しかし、必要なスペースと引用の量が多すぎるため、迷惑で退屈で小さな問題が発生しやすいプログラミング作業です。タスクを実行するために必要な最小限のPerl（またはPython）サブセットを学ぶのははるかに簡単です...そして一度実行した後は、後で同様のタスクを簡単に実行できます。

ほとんど午前2時で寝る必要があるため、この時点ではそのようなスクリプトの基本バージョンを作成する時間さえありません。とにかく、あなたの質問は、Oracleがデータを処理する方法の詳細を実際に提供していません。

PS：あなたの質問に投稿した2つのシェルコードの例を見ると、1行のコードで何かをするのが好きだと思います。 Quipは便利ですが、常に問題に対する最善の解決策ではなく、一般的に悪い解決策です。 awkやPerlなどの言語でスクリプトを書くのを恐れないでください。スタンドアロンとして使用するか、シェルスクリプトの一部としてスクリプトを使用することは、UnixとLinuxを使用する方法です。

多くのコマンドで構成された長く複雑なパイプラインを使用してシェルでデータを処理しようとすると、awkまたはPerlでカスタムツールを作成するよりもはるかに難しくなり、シェルパイプラインが脆弱になる可能性があります。確かに数倍遅くなります。小さなデータファイルと単純な処理操作の場合、パフォーマンスは重要ではない可能性があります。大量のデータおよび/または複雑な処理の場合、これは実行時間が数秒から数時間の間の差を意味する可能性があります。

Archive::Zip以下は、PerlでDBI同じタスクを実行するためにand /または＆モジュールを使用するいくつかの例ですDBD。これらのPerlスクリプトは.zipアーカイブから直接一致するファイルを読み取るため、.zipファイルを抽出する一時ディレクトリは必要ありません。

最初の例では、bash + awkスクリプトの機能を複製します。

$ cat process-zip-files.pl
#!/usr/bin/perl

use strict;

use Archive::Zip;

# First arg is the source directory. defaults to ./
my $dir = shift // '.';

foreach my $zf (glob "$dir/*.zip") {
  # open the zip file
  my $zip = Archive::Zip->new($zf);

  # get the list of files ending with a dot and at least one digit
  my @txt = grep { /\.\d+$/ } $zip->memberNames();

  # iterate over each matching filename
  foreach my $f (@txt) {
    my @data = ();

    # Iterate over each line of the file ($f).  This code is fine
    # for smallish files, but it would be better to use the
    # Archive::Zip::MemberRead module for large files to avoid
    # reading the entire file into memory at once.
    foreach (split /\n/, $zip->contents($f)) {
      if (m/^999\s/) {
        # perl substr offsets start at 0, not 1.  So the
        # next line grabs 15 chars, starting from char 20
        # and adds the string to the @data array.
        push @data, substr($_,19,15);
      }
    };

    # Now do something with the data from this file
    @data = map { "'$_'" } @data; # quote each element of @data
    print "(", join(",",@data), ")\n";

  }  # end of current member file
} # end of current zipfile

$ ./process-zip-files.pl 
('123456789012345','234567890123456')

単にデータを印刷する代わりに、データベースと直接対話することができます。ここでは、あいまいでやや役に立たない例だけを提示します。なぜなら、データベーステーブル構造が何であるか、.NNNファイルから抽出されたデータで実際に何をしたいのかわからないからです。

$ cat process-zip-files-sql.pl
#!/usr/bin/perl

use strict;

use Archive::Zip;
use Archive::Zip::MemberRead;
use DBI;

# First arg is the source directory. defaults to ./
my $dir = shift // '.';

# I don't have Oracle, and I couldn't be bothered setting up
# a database, table, and login account on mysql or postgres
# for this example, so I'll use SQLite.  Other databases are
# just as easy to connect to, but the connect() call will
# require other details like hostname, port, login, password,
# etc.
#
# Set up a database handle ($dbh) to the sqlite db called
# "notoracle.sqlite3":

my $dbname='notoracle.sqlite3';
my $dbh = DBI->connect("dbi:SQLite:dbname=$dbname","","");

foreach my $zf (glob "$dir/*.zip") {
  my $zip = Archive::Zip->new($zf);
  my @txt = grep { /\.\d+$/ } $zip->memberNames();

  foreach my $f (@txt) {
    my @data = ();

    # This example uses Archive::Zip::MemberRead, just to show
    # how to use it.
    my $fh  = Archive::Zip::MemberRead->new($zip, $f);
    while (defined(my $l = $fh->getline())) {
      if ($l =~ m/^999\s/) {
        push @data, substr($l,19,15);
      }
    };
    $fh->close();

    # Example 1: print matching records (each element needs to be
    # quoted when using IN, can't use placeholders):

    my @qdata = map { "'$_'" } @data; # quote each element of @data
    my $values = join(",",@qdata);
    my $sql = "select * from mytable where myfield in ($values)";
    print join(",", $dbh->selectrow_array($sql)),"\n";

    # Example 2 - using a placeholder ?, one element of @data
    # at a time.  There is no need to quote each element of
    # the @data array because placeholders handle quoting
    # automagically if and when required, depending on the data
    # type of the database field.

    my $sth = $dbh->prepare('select * from mytable where myfield = ?');
    foreach my $d (@data) {
      while (my @row = $sth->fetchrow_array($sql,undef,$d)) {
        print join(",",@row), "\n";
      }
    }
  }  # end of current member file
} # end of current zipfile

この例は機能的ではない概念的な例なので、出力例はありません。同じ理由で、このコードはテストされておらず、マイナーなバグが含まれる可能性があります。うまくコンパイルされていますが、perl -w -c process-zip-files-sql.pl実際に機能したり便利なことをするという保証はありません。