マウスボタンコードで使用するときにxbindkeysがマウスクリックを無視するのを防ぐ

Question

ついに解決しましたが、回避策は少し複雑です（とにかくWindowsとMacのバージョンと比較して）。

アイデアは、xinputUSBマウスのマウスボタンを再マップしてボタンを無効にしますが、マウスの動きは維持することです。

その後、マウスボタンイベントを受け取り、evtest検出されたボタンの組み合わせに対してマウスコードコマンドをトリガーするか、組み合わせが検出されない場合は通常のボタンイベントをトリガーします。

設置xinputとevtest
evtestUSBマウスを起動して記録してみてください（類似/dev/input/event3）
実行しxinput -listてデバイスIDを書き留めます。
実行xinput set-button-map {id} 0 0 0 0 0 0 0 0 0 0（0 10個）
走るevtest /dev/input/event3 | ./mouse-chording.pl

コンテンツmouse-chording.pl:

#!/usr/bin/perl -wlnF/\s|,/

BEGIN
{
    our %btns         = (272 => 0, 273 => 0, 274 => 0);
    our $active_chord = 0;

    # mouse button codes
    our $left_code   = 272;
    our $right_code  = 273;
    our $middle_code = 274;
    our $scroll_code = 8;
}

# only handle events
next unless  0 == index $_, 'Event';
next unless -1 == index $_, 'SYN';

# extract event values
my ($time, $type, $code, $value) = @F[2, 5, 9, 13];

# skip mouse movements and hi-res scroll
next if $code == 11;
next if $type == 2 && $code != 8;

# keep track of pressed buttons
$btns{$code} = $value;

# emulate button presses
if ( ($code == $left_code   && !($btns{$right_code} || $btns{$middle_code}))
  || ($code == $right_code  && !($btns{$left_code}  || $btns{$middle_code}))
  || ($code == $middle_code && !($btns{$left_code}  || $btns{$right_code})) )
{
    if ($code == $left_code)
    {
        # left button can be held for selecting text
        system $value ? "xdotool mousedown 1&" : "xdotool mouseup 1&";
    }
    elsif($value == 0 && not $active_chord)
    {
        # middle and right will only trigger click - cannot be held
        system "xdotool click " . ($code == $middle_code ? 2 : 3) . "&";
    }

    $active_chord = 0;
    next;
}
# emulate scroll wheel
elsif ($code == 8)
{
    system( sprintf("xdotool click %d&", $value > 0 ? 4 : 5) );
}

# only do chords when button is pressed (not released)
next unless $value;

# Left + Middle = Cut
if ($btns{$left_code} && $code == $middle_code)
{
    system "xdotool mouseup 1&"; # prevent accidental selection after snarf
    system "xdotool key ctrl+c key ctrl+x&";
    $active_chord = 1;
    next;
}

# Left + Right = Paste
if ($btns{$left_code} && $code == $right_code)
{
    system "xdotool key ctrl+v&";
    $active_chord = 1;
    next;
}

END
{
    # release buttons to prevent getting stuck when closing
    system "xdotool mouseup $_&" for (1..3);
}

このソリューションは、githubのWindowsとMacのバージョンで維持されています。https://github.com/levigutt/mouse-chording/

PRを歓迎します！ :)

Answer 1

ついに解決しましたが、回避策は少し複雑です（とにかくWindowsとMacのバージョンと比較して）。