awk ifsと変数 - 1行から次の行に変数を渡すことはできません

Question

〜のように指摘渡すタレジン、印刷に拡張を使用するのは間違いです$。またはとは異なり、path変数名をその値に拡張するために使用されず、代わりに行のフィールドを参照します（と同様）。bashmakeawk$perl

したがって、コードを機能させるにはそれを削除してください。

BEGIN{
path=""
}
{
    if ($1 ~ /\:/)
        {
        sub(/\:/,"",$1)
        if (substr($1, length,1) ~ /\//)
            {
            path=$1;
            }
        else
            {
            path=$1"/"
            }
        }
    else if (length($0) == 0)
        {}
    else
        print path$1
}

しかし、これは実際には良い解決策ではありません。まず、ルールで初期化awkする必要はなく、定義されていない変数はコンテキストに従ってデフォルトでまたはに設定されます。pathBEGIN""0

また、以下をawk含むすべてのスクリプトは模様そして行動、前者は意味いつ、後者の何します。あなたは一つ持っています。行動常に実行される（null模様）、内部的に（ネストされた）条件を使用して実行するアクションを決定します。

私の解決策は次のとおりです

# BEGIN is actually a pattern making the following rule run only once:
# That is, before any input is read.
BEGIN{
  # Split lines into chunks (fields) separated by ":".
  # This is done by setting the field separator (FS) variable accordingly:
# FS=":"  # this would split lines into fields by ":"

  # Additionally, if a field ends with "/",
  # we consider this part of the separator.
  # So fields should be split by a ":" that *might*
  # be predecessed by a "/".
  # This can be done using a regular expression (RE) FS:
  FS="/?:"  # "?" means "the previous character may occur 0 or 1 times"

  # When printing, we want to join the parts of the paths by "/".
  # That's the sole purpose of the output field separator (OFS) variable:
  OFS="/"
}

# First we want to identify records (i.e. in this [default] case: lines),
# that contain(ed) a ":".
# We can do that without any RE matching, since records are
# automatically split into fields separated by ":".
# So asking >>Does the current line contain a ":"?<< is now the same
# as asking >>Does the current record have more than 1 field?<<.
# Luckily (but not surprisingly), the number of fields (NF) variable
# keeps track of this:
NF>1{  # The follwoing action is run only if are >1 fields.

  # All we want to do in this case, is store everything up to the first ":",
  # without the potential final "/".
  # With our FS choice (see above), that's exactly the 1st field:
  path=$1
}

# The printing should be done only for non-empty lines not containing ":".
# In our case, that translates to a record that has neither 0 nor >1 fields:
NF==1{  # The following action is only run if there is exactly 1 field.

  # In this case, we want to print the path varible (no need for a "$" here)
  # followed by the current line, separated by a "/".
  # Since we defined the proper OFS, we can use "," to join output fields:
  print path,$1  # ($1==$0 since NF==1)
}

それはすべてです。すべてのコメントを削除し、変数名を減らし、[O]FS定義をコマンドラインパラメータに移動すると、次のように簡単に作成できます。

awk -F'/?:' -vOFS=\/ 'NF>1{p=$1}NF==1{print p,$1}' structure-of-home.cnf

Answer 1